[PATCH] gc-steps: probes for tracking each GC step

[Eric Wong <e@80x24.org>]

This should be useful for tracking latency due to GC
---
 tool/gc-steps.stp | 55 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 tool/gc-steps.stp

diff --git a/tool/gc-steps.stp b/tool/gc-steps.stp
new file mode 100644
index 0000000000..db61cd78ed
--- /dev/null
+++ b/tool/gc-steps.stp
@@ -0,0 +1,55 @@
+/*
+ * Logs each GC mark and sweep entry and exit with timestamps
+ *
+ * You will need to change "ruby" to point to an absolute path
+ * of the ruby binary.  Then run "stap /path/to/gc-steps.stp" and run ruby
+ */
+global marks;
+global sweeps;
+global mark_starts;
+global sweep_starts;
+
+function dump_stats() {
+  if (@count(marks)) {
+    printf("  marks % 8u % 8u % 9u % 9u % 9u\n",
+            @min(marks), @max(marks), @avg(marks),
+            @variance(marks), @count(marks));
+    println(@hist_log(marks));
+  }
+  if (@count(sweeps)) {
+    printf(" sweeps % 8u % 8u % 9u % 9u % 9u\n",
+            @min(sweeps), @max(sweeps), @avg(sweeps),
+            @variance(sweeps), @count(sweeps));
+    println(@hist_log(sweeps))
+  }
+}
+
+probe timer.s(5) {
+  dump_stats();
+}
+
+probe process("ruby").mark("gc__sweep__continue__enter")
+{
+  sweep_starts[pid()] = gettimeofday_us();
+}
+
+probe process("ruby").mark("gc__sweep__continue__exit")
+{
+  diff = gettimeofday_us() - sweep_starts[pid()];
+  sweeps <<< diff;
+}
+
+probe process("ruby").mark("gc__marks__continue__enter")
+{
+  mark_starts[pid()] = gettimeofday_us();
+}
+
+probe process("ruby").mark("gc__marks__continue__exit")
+{
+  diff = gettimeofday_us() - mark_starts[pid()];
+  marks <<< diff;
+}
+
+probe end {
+  dump_stats();
+}
-- 
EW