public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 000a0385a63df4eec329557c3985bb9fa7848407 11179 bytes (raw)
name: t/search.t 	 # note: path name is non-authoritative(*)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
 
# Copyright (C) 2015 all contributors <meta@public-inbox.org>
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
use strict;
use warnings;
use Test::More;
eval { require PublicInbox::SearchIdx; };
plan skip_all => "Xapian missing for search" if $@;
use File::Temp qw/tempdir/;
use Email::MIME;
my $tmpdir = tempdir('pi-search-XXXXXX', TMPDIR => 1, CLEANUP => 1);
my $git_dir = "$tmpdir/a.git";
my ($root_id, $last_id);

is(0, system(qw(git init -q --bare), $git_dir), "git init (main)");
eval { PublicInbox::Search->new($git_dir) };
ok($@, "exception raised on non-existent DB");

my $rw = PublicInbox::SearchIdx->new($git_dir, 1);
$rw->_xdb_acquire;
$rw->_xdb_release;
$rw = undef;
my $ro = PublicInbox::Search->new($git_dir);
my $rw_commit = sub {
	$rw->{xdb}->commit_transaction if $rw && $rw->{xdb};
	$rw = PublicInbox::SearchIdx->new($git_dir, 1);
	$rw->_xdb_acquire->begin_transaction;
};

{
	my $root = Email::MIME->create(
		header_str => [
			Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
			Subject => 'Hello world',
			'Message-ID' => '<root@s>',
			From => 'John Smith <js@example.com>',
			To => 'list@example.com',
		],
		body => "\\m/\n");
	my $last = Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
			Subject => 'Re: Hello world',
			'In-Reply-To' => '<root@s>',
			'Message-ID' => '<last@s>',
			From => 'John Smith <js@example.com>',
			To => 'list@example.com',
			Cc => 'foo@example.com',
		],
		body => "goodbye forever :<\n");

	my $rv;
	$rw_commit->();
	$root_id = $rw->add_message($root);
	is($root_id, int($root_id), "root_id is an integer: $root_id");
	$last_id = $rw->add_message($last);
	is($last_id, int($last_id), "last_id is an integer: $last_id");
}

sub filter_mids {
	my ($res) = @_;
	sort(map { $_->mid } @{$res->{msgs}});
}

{
	$rw_commit->();
	$ro->reopen;
	my $found = $ro->lookup_message('<root@s>');
	ok($found, "message found");
	is($root_id, $found->{doc_id}, 'doc_id set correctly');
	is($found->mid, 'root@s', 'mid set correctly');
	ok(int($found->thread_id) > 0, 'thread_id is an integer');

	my ($res, @res);
	my @exp = sort qw(root@s last@s);

	$res = $ro->query('s:(Hello world)');
	@res = filter_mids($res);
	is_deeply(\@res, \@exp, 'got expected results for s:() match');

	$res = $ro->query('s:"Hello world"');
	@res = filter_mids($res);
	is_deeply(\@res, \@exp, 'got expected results for s:"" match');

	$res = $ro->query('s:"Hello world"', {limit => 1});
	is(scalar @{$res->{msgs}}, 1, "limit works");
	my $first = $res->{msgs}->[0];

	$res = $ro->query('s:"Hello world"', {offset => 1});
	is(scalar @{$res->{msgs}}, 1, "offset works");
	my $second = $res->{msgs}->[0];

	isnt($first, $second, "offset returned different result from limit");
}

# ghost vivication
{
	$rw_commit->();
	my $rmid = '<ghost-message@s>';
	my $reply_to_ghost = Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
			Subject => 'Re: ghosts',
			'Message-ID' => '<ghost-reply@s>',
			'In-Reply-To' => $rmid,
			From => 'Time Traveler <tt@example.com>',
			To => 'list@example.com',
		],
		body => "-_-\n");

	my $rv;
	my $reply_id = $rw->add_message($reply_to_ghost);
	is($reply_id, int($reply_id), "reply_id is an integer: $reply_id");

	my $was_ghost = Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:01 +0000',
			Subject => 'ghosts',
			'Message-ID' => $rmid,
			From => 'Laggy Sender <lag@example.com>',
			To => 'list@example.com',
		],
		body => "are real\n");

	my $ghost_id = $rw->add_message($was_ghost);
	is($ghost_id, int($ghost_id), "ghost_id is an integer: $ghost_id");
	ok($ghost_id < $reply_id, "ghost vivified from earlier message");
}

# search thread on ghost
{
	$rw_commit->();
	$ro->reopen;

	# subject
	my $res = $ro->query('ghost');
	my @exp = sort qw(ghost-message@s ghost-reply@s);
	my @res = filter_mids($res);
	is_deeply(\@res, \@exp, 'got expected results for Subject match');

	# body
	$res = $ro->query('goodbye');
	is($res->{msgs}->[0]->mid, 'last@s', 'got goodbye message body');
}

# long message-id
{
	$rw_commit->();
	$ro->reopen;
	my $long_mid = 'last' . ('x' x 60). '@s';

	my $long = Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
			Subject => 'long message ID',
			'References' => '<root@s> <last@s>',
			'In-Reply-To' => '<last@s>',
			'Message-ID' => "<$long_mid>",
			From => '"Long I.D." <long-id@example.com>',
			To => 'list@example.com',
		],
		body => "wut\n");
	my $long_id = $rw->add_message($long);
	is($long_id, int($long_id), "long_id is an integer: $long_id");

	$rw_commit->();
	$ro->reopen;
	my $res;
	my @res;

	my $long_reply_mid = 'reply-to-long@1';
	my $long_reply = Email::MIME->create(
		header_str => [
			Subject => 'I break references',
			Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
			'Message-ID' => "<$long_reply_mid>",
			# No References:
			# 'References' => '<root@s> <last@s> <'.$long_mid.'>',
			'In-Reply-To' => "<$long_mid>",
			From => '"no1 <no1@example.com>',
			To => 'list@example.com',
		],
		body => "no References\n");
	ok($rw->add_message($long_reply) > $long_id, "inserted long reply");

	$rw_commit->();
	$ro->reopen;
	my $t = $ro->get_thread('root@s');
	is($t->{total}, 4, "got all 4 mesages in thread");
	my @exp = sort($long_reply_mid, 'root@s', 'last@s', $long_mid);
	@res = filter_mids($t);
	is_deeply(\@res, \@exp, "get_thread works");
}

# quote prioritization
{
	$rw_commit->();
	$rw->add_message(Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:01 +0000',
			Subject => 'Hello',
			'Message-ID' => '<quote@a>',
			From => 'Quoter <quoter@example.com>',
			To => 'list@example.com',
		],
		body => "> theatre illusions\nfade\n"));

	$rw->add_message(Email::MIME->create(
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:02 +0000',
			Subject => 'Hello',
			'Message-ID' => '<nquote@a>',
			From => 'Non-Quoter<non-quoter@example.com>',
			To => 'list@example.com',
		],
		body => "theatre\nfade\n"));
	my $res = $rw->query("theatre");
	is($res->{total}, 2, "got both matches");
	is($res->{msgs}->[0]->mid, 'nquote@a', "non-quoted scores higher");
	is($res->{msgs}->[1]->mid, 'quote@a', "quoted result still returned");

	$res = $rw->query("illusions");
	is($res->{total}, 1, "got a match for quoted text");
	is($res->{msgs}->[0]->mid, 'quote@a',
		"quoted result returned if nothing else");
}

# circular references
{
	my $s = 'foo://'. ('Circle' x 15).'/foo';
	my $doc_id = $rw->add_message(Email::MIME->create(
		header => [ Subject => $s ],
		header_str => [
			Date => 'Sat, 02 Oct 2010 00:00:01 +0000',
			'Message-ID' => '<circle@a>',
			'References' => '<circle@a>',
			'In-Reply-To' => '<circle@a>',
			From => 'Circle <circle@example.com>',
			To => 'list@example.com',
		],
		body => "LOOP!\n"));
	ok($doc_id > 0, "doc_id defined with circular reference");
	my $smsg = $rw->lookup_message('circle@a');
	is($smsg->references, '', "no references created");
	my $msg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
	is($s, $msg->subject, 'long subject not rewritten');
}

{
	my $str = eval {
		my $mbox = 't/utf8.mbox';
		open(my $fh, '<', $mbox) or die "failed to open mbox: $mbox\n";
		local $/;
		<$fh>
	};
	$str =~ s/\AFrom [^\n]+\n//s;
	my $mime = Email::MIME->new($str);
	my $doc_id = $rw->add_message($mime);
	ok($doc_id > 0, 'message indexed doc_id with UTF-8');
	my $smsg = $rw->lookup_message('testmessage@example.com');
	my $msg = PublicInbox::SearchMsg->load_doc($smsg->{doc});

	is($mime->header('Subject'), $msg->subject, 'UTF-8 subject preserved');
}

{
	my $res = $ro->query('d:19931002..20101002');
	ok(scalar @{$res->{msgs}} > 0, 'got results within range');
	$res = $ro->query('d:20101003..');
	is(scalar @{$res->{msgs}}, 0, 'nothing after 20101003');
	$res = $ro->query('d:..19931001');
	is(scalar @{$res->{msgs}}, 0, 'nothing before 19931001');
}

# names and addresses
{
	my $res = $ro->query('t:list@example.com');
	is(scalar @{$res->{msgs}}, 6, 'searched To: successfully');
	foreach my $smsg (@{$res->{msgs}}) {
		like($smsg->to, qr/\blist\@example\.com\b/, 'to appears');
	}

	$res = $ro->query('tc:list@example.com');
	is(scalar @{$res->{msgs}}, 6, 'searched To+Cc: successfully');
	foreach my $smsg (@{$res->{msgs}}) {
		my $tocc = join("\n", $smsg->to, $smsg->cc);
		like($tocc, qr/\blist\@example\.com\b/, 'tocc appears');
	}

	foreach my $pfx ('tcf:', 'c:') {
		$res = $ro->query($pfx . 'foo@example.com');
		is(scalar @{$res->{msgs}}, 1,
			"searched $pfx successfully for Cc:");
		foreach my $smsg (@{$res->{msgs}}) {
			like($smsg->cc, qr/\bfoo\@example\.com\b/,
				'cc appears');
		}
	}

	foreach my $pfx ('', 'tcf:', 'f:') {
		$res = $ro->query($pfx . 'Laggy');
		is(scalar @{$res->{msgs}}, 1,
			"searched $pfx successfully for From:");
		foreach my $smsg (@{$res->{msgs}}) {
			like($smsg->from, qr/Laggy Sender/,
				"From appears with $pfx");
		}
	}
}

{
	$rw_commit->();
	$ro->reopen;
	my $res = $ro->query('b:hello');
	is(scalar @{$res->{msgs}}, 0, 'no match on body search only');
	$res = $ro->query('bs:smith');
	is(scalar @{$res->{msgs}}, 0,
		'no match on body+subject search for From');

	$res = $ro->query('q:theatre');
	is(scalar @{$res->{msgs}}, 1, 'only one quoted body');
	like($res->{msgs}->[0]->from, qr/\AQuoter/, 'got quoted body');

	$res = $ro->query('nq:theatre');
	is(scalar @{$res->{msgs}}, 1, 'only one non-quoted body');
	like($res->{msgs}->[0]->from, qr/\ANon-Quoter/, 'got non-quoted body');

	foreach my $pfx (qw(b: bs:)) {
		$res = $ro->query($pfx . 'theatre');
		is(scalar @{$res->{msgs}}, 2, "searched both bodies for $pfx");
		like($res->{msgs}->[0]->from, qr/\ANon-Quoter/,
			"non-quoter first for $pfx");
	}
}

{
	my $part1 = Email::MIME->create(
                 attributes => {
                     content_type => 'text/plain',
                     disposition  => 'attachment',
                     charset => 'US-ASCII',
		     encoding => 'quoted-printable',
		     filename => 'attached_fart.txt',
                 },
                 body_str => 'inside the attachment',
	);
	my $part2 = Email::MIME->create(
                 attributes => {
                     content_type => 'text/plain',
                     disposition  => 'attachment',
                     charset => 'US-ASCII',
		     encoding => 'quoted-printable',
		     filename => 'part_deux.txt',
                 },
                 body_str => 'inside another',
	);
	my $amsg = Email::MIME->create(
		header_str => [
			Subject => 'see attachment',
			'Message-ID' => '<file@attached>',
			From => 'John Smith <js@example.com>',
			To => 'list@example.com',
		],
		parts => [ $part1, $part2 ],
	);
	ok($rw->add_message($amsg), 'added attachment');
	$rw_commit->();
	$ro->reopen;
	my $n = $ro->query('n:attached_fart.txt');
	is(scalar @{$n->{msgs}}, 1, 'got result for n:');
	my $res = $ro->query('part_deux.txt');
	is(scalar @{$res->{msgs}}, 1, 'got result without n:');
	is($n->{msgs}->[0]->mid, $res->{msgs}->[0]->mid,
		'same result with and without');
	my $txt = $ro->query('"inside another"');
	is($txt->{msgs}->[0]->mid, $res->{msgs}->[0]->mid,
		'search inside text attachments works');
}

done_testing();

1;

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git